blob: 584af8acde0f6ab8cf1ae415f8ac70aa6e31a656 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
|
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$
EAPI=5
inherit eutils git-2 linux-info systemd toolchain-funcs user
DESCRIPTION="Tvheadend is a TV streaming server and digital video recorder"
HOMEPAGE="https://tvheadend.org/"
EGIT_REPO_URI="git://github.com/tvheadend/tvheadend.git"
LICENSE="GPL-3"
SLOT="0"
KEYWORDS=""
IUSE="avahi +dvb +dvbscan ffmpeg libav imagecache inotify uriparser xmltv zlib"
RDEPEND="dev-libs/openssl:=
virtual/libiconv
avahi? ( net-dns/avahi )
ffmpeg? (
!libav? ( media-video/ffmpeg:0= )
libav? ( media-video/libav:= )
)
uriparser? ( dev-libs/uriparser )
zlib? ( sys-libs/zlib )"
DEPEND="${RDEPEND}
dvb? ( virtual/linuxtv-dvb-headers )
virtual/pkgconfig"
RDEPEND+="
dvbscan? ( media-tv/linuxtv-dvb-apps )
xmltv? ( media-tv/xmltv )"
CONFIG_CHECK="~INOTIFY_USER"
DOCS=( README.md )
pkg_setup() {
enewuser tvheadend -1 -1 /dev/null video
}
src_prepare() {
# remove '-Werror' wrt bug #438424
sed -e 's:-Werror::' -i Makefile || die 'sed failed!'
}
src_configure() {
econf --prefix="${EPREFIX}"/usr \
--datadir="${EPREFIX}"/usr/share \
--disable-ccache \
--disable-dvbscan \
$(use_enable avahi) \
$(use_enable dvb linuxdvb) \
$(use_enable ffmpeg libav) \
$(use_enable imagecache) \
$(use_enable inotify) \
$(use_enable uriparser) \
$(use_enable zlib)
}
src_compile() {
emake CC="$(tc-getCC)"
}
src_install() {
default
newinitd "${FILESDIR}/tvheadend.initd" tvheadend
newconfd "${FILESDIR}/tvheadend.confd" tvheadend
systemd_dounit "${FILESDIR}/tvheadend.service"
dodir /etc/tvheadend
fperms 0700 /etc/tvheadend
fowners tvheadend:video /etc/tvheadend
}
pkg_postinst() {
elog "The Tvheadend web interface can be reached at:"
elog "http://localhost:9981/"
elog
elog "Make sure that you change the default username"
elog "and password via the Configuration / Access control"
elog "tab in the web interface."
}
|
GitWeb