blob: 81505f159ae1c00cdaabdc9f363b41b70a44f9b7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
DESCRIPTION="A modern multi-purpose calculator library"
HOMEPAGE="https://qalculate.github.io/"
SRC_URI="https://github.com/Qalculate/${PN}/releases/download/v${PV}/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0/21"
KEYWORDS="~alpha amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
IUSE="curl icu gnuplot readline"
DEPEND="
dev-libs/gmp:0=
dev-libs/libxml2:2
dev-libs/mpfr:0=
virtual/libiconv
curl? ( net-misc/curl )
icu? ( dev-libs/icu:= )
readline? ( sys-libs/readline:0= )"
RDEPEND="${DEPEND}
gnuplot? ( >=sci-visualization/gnuplot-3.7 )"
BDEPEND="
dev-util/intltool
sys-devel/gettext
virtual/pkgconfig"
src_prepare() {
default
cat >po/POTFILES.skip <<-EOF || die
# Required by make check
data/currencies.xml.in
data/datasets.xml.in
data/elements.xml.in
data/functions.xml.in
data/planets.xml.in
data/prefixes.xml.in
data/units.xml.in
data/variables.xml.in
src/defs2doc.cc
EOF
}
src_configure() {
econf \
--disable-static \
$(use_with curl libcurl) \
$(use_with gnuplot gnuplot-call) \
$(use_with icu) \
$(use_with readline)
}
src_install() {
# docs/reference/Makefile.am -> referencedir=
emake \
DESTDIR="${D}" \
referencedir="${EPREFIX}/usr/share/doc/${PF}/html" \
install
einstalldocs
find "${ED}" -name '*.la' -delete || die
}
|
GitWeb
