blob: 172f1ef054f7f027df4dcb43b980bb0f1cd8bad6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
MY_PV=${PV//./_}
MY_P=${PN}-${MY_PV}
inherit toolchain-funcs
DESCRIPTION="Ethernet NIC Queue stats viewer"
HOMEPAGE="https://github.com/isc-projects/ethq"
SRC_URI="https://github.com/isc-projects/ethq/archive/v${MY_PV}.tar.gz -> ${MY_P}.tar.gz"
LICENSE="MPL-2.0"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="test"
RESTRICT="!test? ( test )"
DEPEND="sys-libs/ncurses:="
RDEPEND="${DEPEND}"
S="${WORKDIR}/${MY_P}"
src_prepare() {
default
# Respect FLAGS, remove Werror
sed -i -e '/CXXFLAGS/s/= -O3/+=/' \
-e '/CXXFLAGS/s/ -Werror//' \
-e '/LDFLAGS/s/=/+=/' Makefile || die "sed failed for Makefile"
if ! use test ; then
sed -i '/TARGETS/s/ethq_test//' Makefile \
|| die "sed failed for USE flag test"
fi
}
src_compile() {
# override for ncurses[tinfo]
emake CXX="$(tc-getCXX)" LIBS_CURSES="$($(tc-getPKG_CONFIG) --libs ncurses)"
}
src_test() {
local driver
for driver in tests/* ; do
"${S}"/ethq_test "${driver##*/}" "${driver}" \
|| die "test failed on ${driver}"
done
}
src_install() {
einstalldocs
dobin ethq
}
|
GitWeb
