blob: d730ab8fab43ccfe3e58cd93a6de5635c975d933 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
# Copyright 1999-2018 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=5
XORG_MULTILIB=yes
inherit xorg-2
DESCRIPTION="X.Org libdrm library"
HOMEPAGE="https://dri.freedesktop.org/"
if [[ ${PV} = 9999* ]]; then
EGIT_REPO_URI="https://anongit.freedesktop.org/git/mesa/drm.git"
else
SRC_URI="https://dri.freedesktop.org/libdrm/${P}.tar.bz2"
KEYWORDS="alpha amd64 arm ~arm64 hppa ia64 ~mips ppc ppc64 ~s390 ~sh sparc x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux"
fi
VIDEO_CARDS="amdgpu exynos freedreno intel nouveau omap radeon tegra vc4 vivante vmware"
for card in ${VIDEO_CARDS}; do
IUSE_VIDEO_CARDS+=" video_cards_${card}"
done
IUSE="${IUSE_VIDEO_CARDS} libkms valgrind"
RESTRICT="test" # see bug #236845
RDEPEND=">=dev-libs/libpthread-stubs-0.3-r1:=[${MULTILIB_USEDEP}]
video_cards_intel? ( >=x11-libs/libpciaccess-0.13.1-r1:=[${MULTILIB_USEDEP}] )"
DEPEND="${RDEPEND}
valgrind? ( dev-util/valgrind )"
src_prepare() {
if [[ ${PV} = 9999* ]]; then
# tests are restricted, no point in building them
sed -ie 's/tests //' "${S}"/Makefile.am
fi
xorg-2_src_prepare
epatch_user
}
src_configure() {
XORG_CONFIGURE_OPTIONS=(
# Udev is only used by tests now.
--disable-udev
--disable-cairo-tests
$(use_enable video_cards_amdgpu amdgpu)
$(use_enable video_cards_exynos exynos-experimental-api)
$(use_enable video_cards_freedreno freedreno)
$(use_enable video_cards_intel intel)
$(use_enable video_cards_nouveau nouveau)
$(use_enable video_cards_omap omap-experimental-api)
$(use_enable video_cards_radeon radeon)
$(use_enable video_cards_tegra tegra-experimental-api)
$(use_enable video_cards_vc4 vc4)
$(use_enable video_cards_vivante etnaviv-experimental-api)
$(use_enable video_cards_vmware vmwgfx)
$(use_enable libkms)
# valgrind installs its .pc file to the pkgconfig for the primary arch
--enable-valgrind=$(usex valgrind auto no)
)
xorg-2_src_configure
}
|
GitWeb
