x11-misc/fireflies/fireflies-2.08.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41

# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$

EAPI=5
inherit autotools multilib

DESCRIPTION="Fireflies screensaver: Wicked cool eye candy"
HOMEPAGE="https://github.com/mpcomplete/fireflies"
SRC_URI="https://github.com/mpcomplete/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="GPL-2 icu"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE=""

RDEPEND="media-libs/libsdl[X,opengl,video]
	virtual/glu
	virtual/opengl
	x11-libs/libX11"
DEPEND="${RDEPEND}
	sys-devel/autoconf-archive"  # for AX_CXX_BOOL macro

DOCS=( ChangeLog README.md TODO )

src_prepare() {
	eautoreconf
}

src_configure() {
	econf \
		--with-confdir=/usr/share/xscreensaver/config \
		--with-bindir="/usr/$(get_libdir)/misc/xscreensaver"
}

src_install() {
	exeinto /usr/lib  # FHS: internal binaries
	newexe {,${PN}-}add-xscreensaver

	default
}