version bump

Package-Manager: portage-2.2.0_alpha84/cvs/Linux x86_64

4 files changed, 292 insertions, 25 deletions

diff --git a/media-video/ffmpeg/ChangeLog b/media-video/ffmpeg/ChangeLog
index bad9de59e1a3..259c3fefc1a5 100644
--- a/media-video/ffmpeg/ChangeLog
+++ b/media-video/ffmpeg/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-video/ffmpeg
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/ffmpeg/ChangeLog,v 1.518 2012/01/02 13:45:09 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/ffmpeg/ChangeLog,v 1.519 2012/01/05 14:09:56 aballier Exp $
+
+*ffmpeg-0.9.1 (05 Jan 2012)
+
+  05 Jan 2012; Alexis Ballier <aballier@gentoo.org> +ffmpeg-0.9.1.ebuild:
+  version bump
 
   02 Jan 2012; Samuli Suominen <ssuominen@gentoo.org> metadata.xml:
   USE description for flag "neon" is in use.desc now.
diff --git a/media-video/ffmpeg/Manifest b/media-video/ffmpeg/Manifest
index 3becde86081a..b68b8bebc12d 100644
--- a/media-video/ffmpeg/Manifest
+++ b/media-video/ffmpeg/Manifest
@@ -3,20 +3,18 @@ Hash: SHA1
 
 AUX ffmpeg-0.7.6-fix_ppc64_32ul.patch 1094 RMD160 b765f1f8420701e6d9447391dd498f6807b2e2e7 SHA1 f4fd276e9a88d815657282d67b716dc793f30988 SHA256 b6e60ba7f9d179b8b2ba03cf74694d1e92e6fc6d4626cda258ab1af50e0afea4
 DIST ffmpeg-0.7.8.tar.bz2 4530406 RMD160 8f69a6bc5caaba4e3d440c2d5dc96a946454a52c SHA1 df4983c028a61d4bf3baceab3bae535b91b8928a SHA256 548197968e69b732c12b2cad3173eb6933a9573a7b1f5b29be36d31b9977c9f3
+DIST ffmpeg-0.9.1.tar.bz2 4974636 RMD160 2fac1b2520418d9e1b2b821e46c94a650a8770f3 SHA1 89326f93902aee49dac659a63b39b0f69be0e7ee SHA256 f6df7f47d8b63aa14c5a9d64d72f61966b03631ebb6982e38802b9da128195ca
 DIST ffmpeg-0.9.tar.bz2 4954965 RMD160 56e1e240363d4f1bc09390f5a3893a1b6b362908 SHA1 5f4118496ebe8fc37e8f11cf0303f6f7c85756f9 SHA256 2a9eb7795e6c1ad746aa2cc0fce9f71ec3763f610e362530ab277c6bc327d705
 EBUILD ffmpeg-0.7.8.ebuild 8434 RMD160 ee37ec983306aaa4bf464a6bcccd7072c8490052 SHA1 7712cefb7ac062070f1d367d250204e95ea9e709 SHA256 f295745280616cc04724889e2d5b02a9648321e572c256e959989610c0b774e3
+EBUILD ffmpeg-0.9.1.ebuild 8269 RMD160 a2f22d3ed67b55f451fad959c64ebc65c0304903 SHA1 3b59f0faedcfb7279c5e69ab8bc31ecec37ac689 SHA256 b684283ebe032af9c0cfff31dfe50d29fb688963337b5b9283cdb7eee703d8a5
 EBUILD ffmpeg-0.9.ebuild 8210 RMD160 f0937227d1e307474d859b0a37721875ea273cc9 SHA1 846ae7fd0cabc16a7ac3fcd1496d60734904c142 SHA256 62b4447f6523b7f7c124a782adfe1cbe41b44a94723ee249d9f7e761f66c0959
 EBUILD ffmpeg-9999.ebuild 8311 RMD160 12072c1d7303a90b23229e3e5bafa428c6e93b86 SHA1 093031a529e9f70943ea21435de6cfcc37bd84d7 SHA256 23fe00ad8d2d53a12251c345f82d349628d3519c3121eb815399df1f1e8a354e
-MISC ChangeLog 74261 RMD160 52ef9295bd7a2d2d1dae9e1d3c4119547dcb2417 SHA1 8d7c262e053a5142df14a26f668264cec8ecef67 SHA256 b54468a5e2dfe87ee2c5ca5eb2b321a76d364a1d1e11f4816c25acb2641a4616
+MISC ChangeLog 74379 RMD160 7598a02288ca4f8d9cbad65987f0caa6062b56aa SHA1 e22de0da144fef553babb9d8c427ceb674c53779 SHA256 dc5f180a72f33b823b5142c719ebf7d6b6d0195ad2ec8260689b540208f66de9
 MISC metadata.xml 3187 RMD160 1449b9f14d574861c1126ae3d48b2512e5c21a10 SHA1 022bfbc48a9eeb5b35246c20709322cc1cceabaf SHA256 9e1ce3cad4c6be94e164d5df3fcf1ac38603de044be5c6bd8fa273adb4d84abb
 -----BEGIN PGP SIGNATURE-----
 Version: GnuPG v2.0.18 (GNU/Linux)
 
-iQEcBAEBAgAGBQJPAbR7AAoJEEdUh39IaPFN+IgH/2q1BWBD5SXCFklVrVFUEFu6
-+jAdjNjgc0gZV0Hwt/E+tCkKYvWHQimLLKJujlD11kftgTu4Od01SE/hP3STZdqz
-goe8fA78QRP+UuRay7uy78HnoqaheQjhCYyODlbYsRlB1ggSLWVlSWDov2mAhKn3
-R8crqodXihKFgLtAhnSf9eZhV4x/Na2LHb/tu/ah+KiKRgeQnSIFCheVAK8jI+SF
-cwU+CKe2soXxP3LXELoakAKTlKIxFmka5a3yaoXqGEvyiJ+rT1iuQYfFJ9i5ja9i
-Ldk0KllzB2ZqVFLkLcmmtRVsoeGDGyR9oSL0uQzZGSZMzhYGERLnw921OWk84Ds=
-=AdUq
+iEYEARECAAYFAk8FrzoACgkQvFcC4BYPU0or5ACfeK8xyMGjTR7qhCAv1cmjqVv1
+8fcAoL6kxqMTR7xzMNPx8d5LNGkyaW7Y
+=Fupb
 -----END PGP SIGNATURE-----
diff --git a/media-video/ffmpeg/ffmpeg-0.9.1.ebuild b/media-video/ffmpeg/ffmpeg-0.9.1.ebuild
new file mode 100644
index 000000000000..4bee790e4f23
--- /dev/null
+++ b/media-video/ffmpeg/ffmpeg-0.9.1.ebuild
@@ -0,0 +1,272 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/ffmpeg/ffmpeg-0.9.1.ebuild,v 1.1 2012/01/05 14:09:56 aballier Exp $
+
+EAPI="4"
+
+SCM=""
+if [ "${PV#9999}" != "${PV}" ] ; then
+	SCM="git-2"
+	EGIT_REPO_URI="git://git.videolan.org/ffmpeg.git"
+fi
+
+inherit eutils flag-o-matic multilib toolchain-funcs ${SCM}
+
+DESCRIPTION="Complete solution to record, convert and stream audio and video. Includes libavcodec."
+HOMEPAGE="http://ffmpeg.org/"
+if [ "${PV#9999}" != "${PV}" ] ; then
+	SRC_URI=""
+elif [ "${PV%_p*}" != "${PV}" ] ; then # Snapshot
+	SRC_URI="mirror://gentoo/${P}.tar.bz2"
+else # Release
+	SRC_URI="http://ffmpeg.org/releases/${P/_/-}.tar.bz2"
+fi
+FFMPEG_REVISION="${PV#*_p}"
+
+LICENSE="GPL-2 amr? ( GPL-3 ) encode? ( aac? ( GPL-3 ) )"
+SLOT="0"
+if [ "${PV#9999}" = "${PV}" ] ; then
+	KEYWORDS="~amd64 ~hppa ~x86-fbsd"
+fi
+IUSE="
+	aac aacplus alsa amr ass avconv bindist +bzip2 cdio celt cpudetection debug
+	dirac doc +encode faac frei0r gnutls gsm +hardcoded-tables ieee1394 jack
+	jpeg2k libv4l modplug mp3 network openal openssl oss pic pulseaudio
+	+qt-faststart rtmp schroedinger sdl speex static-libs test theora threads
+	truetype v4l vaapi vdpau vorbis vpx X x264 xvid +zlib
+	"
+
+# String for CPU features in the useflag[:configure_option] form
+# if :configure_option isn't set, it will use 'useflag' as configure option
+CPU_FEATURES="3dnow:amd3dnow 3dnowext:amd3dnowext altivec avx mmx mmxext:mmx2 ssse3 vis neon iwmmxt"
+
+for i in ${CPU_FEATURES}; do
+	IUSE="${IUSE} ${i%:*}"
+done
+
+RDEPEND="
+	alsa? ( media-libs/alsa-lib )
+	amr? ( media-libs/opencore-amr )
+	ass? ( media-libs/libass )
+	bzip2? ( app-arch/bzip2 )
+	cdio? ( dev-libs/libcdio )
+	celt? ( >=media-libs/celt-0.11.1 )
+	dirac? ( media-video/dirac )
+	encode? (
+		aac? ( media-libs/vo-aacenc )
+		aacplus? ( media-libs/libaacplus )
+		amr? ( media-libs/vo-amrwbenc )
+		faac? ( media-libs/faac )
+		mp3? ( >=media-sound/lame-3.98.3 )
+		theora? ( >=media-libs/libtheora-1.1.1[encode] media-libs/libogg )
+		vorbis? ( media-libs/libvorbis media-libs/libogg )
+		x264? ( >=media-libs/x264-0.0.20111017 )
+		xvid? ( >=media-libs/xvid-1.1.0 )
+	)
+	frei0r? ( media-plugins/frei0r-plugins )
+	gnutls? ( net-libs/gnutls )
+	gsm? ( >=media-sound/gsm-1.0.12-r1 )
+	ieee1394? ( media-libs/libdc1394 sys-libs/libraw1394 )
+	jack? ( media-sound/jack-audio-connection-kit )
+	jpeg2k? ( >=media-libs/openjpeg-1.3-r2 )
+	libv4l? ( media-libs/libv4l )
+	modplug? ( media-libs/libmodplug )
+	openal? ( >=media-libs/openal-1.1 )
+	pulseaudio? ( media-sound/pulseaudio )
+	rtmp? ( >=media-video/rtmpdump-2.2f )
+	sdl? ( >=media-libs/libsdl-1.2.13-r1[audio,video] )
+	schroedinger? ( media-libs/schroedinger )
+	speex? ( >=media-libs/speex-1.2_beta3 )
+	truetype? ( media-libs/freetype:2 )
+	vaapi? ( >=x11-libs/libva-0.32 )
+	vdpau? ( x11-libs/libvdpau )
+	vpx? ( >=media-libs/libvpx-0.9.6 )
+	X? ( x11-libs/libX11 x11-libs/libXext x11-libs/libXfixes )
+	zlib? ( sys-libs/zlib )
+	!media-video/qt-faststart
+"
+
+DEPEND="${RDEPEND}
+	>=sys-devel/make-3.81
+	dirac? ( dev-util/pkgconfig )
+	doc? ( app-text/texi2html )
+	gnutls? ( dev-util/pkgconfig )
+	ieee1394? ( dev-util/pkgconfig )
+	libv4l? ( dev-util/pkgconfig )
+	mmx? ( dev-lang/yasm )
+	rtmp? ( dev-util/pkgconfig )
+	schroedinger? ( dev-util/pkgconfig )
+	test? ( net-misc/wget )
+	truetype? ( dev-util/pkgconfig )
+	v4l? ( sys-kernel/linux-headers )
+"
+# faac is license-incompatible with ffmpeg
+REQUIRED_USE="bindist? ( encode? ( !faac !aacplus ) !openssl )
+	libv4l? ( v4l )
+	test? ( encode zlib )"
+
+S=${WORKDIR}/${P/_/-}
+
+src_prepare() {
+	if [ "${PV%_p*}" != "${PV}" ] ; then # Snapshot
+		export revision=git-N-${FFMPEG_REVISION}
+	fi
+}
+
+src_configure() {
+	local myconf="${EXTRA_FFMPEG_CONF}"
+	# Set to --enable-version3 if (L)GPL-3 is required
+	local version3=""
+
+	# enabled by default
+	for i in debug doc network vaapi vdpau zlib; do
+		use ${i} || myconf="${myconf} --disable-${i}"
+	done
+	use bzip2 || myconf="${myconf} --disable-bzlib"
+	use sdl || myconf="${myconf} --disable-ffplay"
+
+	use cpudetection && myconf="${myconf} --enable-runtime-cpudetect"
+	use openssl && myconf="${myconf} --enable-openssl --enable-nonfree"
+	for i in gnutls avconv ; do
+		use $i && myconf="${myconf} --enable-$i"
+	done
+
+	# Encoders
+	if use encode
+	then
+		use mp3 && myconf="${myconf} --enable-libmp3lame"
+		use aac && { myconf="${myconf} --enable-libvo-aacenc" ; version3=" --enable-version3" ; }
+		use amr && { myconf="${myconf} --enable-libvo-amrwbenc" ; version3=" --enable-version3" ; }
+		for i in theora vorbis x264 xvid; do
+			use ${i} && myconf="${myconf} --enable-lib${i}"
+		done
+		use aacplus && myconf="${myconf} --enable-libaacplus --enable-nonfree"
+		use faac && myconf="${myconf} --enable-libfaac --enable-nonfree"
+	else
+		myconf="${myconf} --disable-encoders"
+	fi
+
+	# libavdevice options
+	use cdio && myconf="${myconf} --enable-libcdio"
+	use ieee1394 && myconf="${myconf} --enable-libdc1394"
+	use openal && myconf="${myconf} --enable-openal"
+	# Indevs
+	# v4l1 is gone since linux-headers-2.6.38
+	myconf="${myconf} --disable-indev=v4l"
+	use v4l || myconf="${myconf} --disable-indev=v4l2"
+	for i in alsa oss jack ; do
+		use ${i} || myconf="${myconf} --disable-indev=${i}"
+	done
+	use X && myconf="${myconf} --enable-x11grab"
+	use pulseaudio && myconf="${myconf} --enable-libpulse"
+	use libv4l && myconf="${myconf} --enable-libv4l2"
+	# Outdevs
+	for i in alsa oss sdl ; do
+		use ${i} || myconf="${myconf} --disable-outdev=${i}"
+	done
+	# libavfilter options
+	use frei0r && myconf="${myconf} --enable-frei0r"
+	use truetype && myconf="${myconf} --enable-libfreetype"
+	use ass && myconf="${myconf} --enable-libass"
+
+	# Threads; we only support pthread for now but ffmpeg supports more
+	use threads && myconf="${myconf} --enable-pthreads"
+
+	# Decoders
+	use amr && { myconf="${myconf} --enable-libopencore-amrwb --enable-libopencore-amrnb" ; version3=" --enable-version3" ; }
+	for i in celt gsm dirac modplug rtmp schroedinger speex vpx; do
+		use ${i} && myconf="${myconf} --enable-lib${i}"
+	done
+	use jpeg2k && myconf="${myconf} --enable-libopenjpeg"
+
+	# CPU features
+	for i in ${CPU_FEATURES}; do
+		use ${i%:*} || myconf="${myconf} --disable-${i#*:}"
+	done
+	if use pic ; then
+		myconf="${myconf} --enable-pic"
+		# disable asm code if PIC is required
+		# as the provided asm decidedly is not PIC for x86.
+		use x86 && myconf="${myconf} --disable-asm"
+	fi
+
+	# Try to get cpu type based on CFLAGS.
+	# Bug #172723
+	# We need to do this so that features of that CPU will be better used
+	# If they contain an unknown CPU it will not hurt since ffmpeg's configure
+	# will just ignore it.
+	for i in $(get-flag march) $(get-flag mcpu) $(get-flag mtune) ; do
+		[ "${i}" = "native" ] && i="host" # bug #273421
+		myconf="${myconf} --cpu=${i}"
+		break
+	done
+
+	# Mandatory configuration
+	myconf="
+		--enable-gpl
+		${version3}
+		--enable-postproc
+		--enable-avfilter
+		--disable-stripping
+		${myconf}"
+
+	# cross compile support
+	if tc-is-cross-compiler ; then
+		myconf="${myconf} --enable-cross-compile --arch=$(tc-arch-kernel) --cross-prefix=${CHOST}-"
+		case ${CHOST} in
+			*freebsd*)
+				myconf="${myconf} --target-os=freebsd"
+				;;
+			mingw32*)
+				myconf="${myconf} --target-os=mingw32"
+				;;
+			*linux*)
+				myconf="${myconf} --target-os=linux"
+				;;
+		esac
+	fi
+
+	# Misc stuff
+	use hardcoded-tables && myconf="${myconf} --enable-hardcoded-tables"
+
+	cd "${S}"
+	./configure \
+		--prefix="${EPREFIX}/usr" \
+		--libdir="${EPREFIX}/usr/$(get_libdir)" \
+		--shlibdir="${EPREFIX}/usr/$(get_libdir)" \
+		--mandir="${EPREFIX}/usr/share/man" \
+		--enable-shared \
+		--cc="$(tc-getCC)" \
+		--cxx="$(tc-getCXX)" \
+		--ar="$(tc-getAR)" \
+		--optflags="${CFLAGS}" \
+		--extra-cflags="${CFLAGS}" \
+		--extra-cxxflags="${CXXFLAGS}" \
+		$(use_enable static-libs static) \
+		${myconf} || die
+}
+
+src_compile() {
+	emake
+
+	if use qt-faststart; then
+		tc-export CC
+		emake -C tools qt-faststart
+	fi
+}
+
+src_install() {
+	emake DESTDIR="${D}" install install-man
+
+	dodoc Changelog README INSTALL
+	dodoc -r doc/*
+
+	if use qt-faststart; then
+		dobin tools/qt-faststart
+	fi
+}
+
+src_test() {
+	LD_LIBRARY_PATH="${S}/libpostproc:${S}/libswscale:${S}/libswresample:${S}/libavcodec:${S}/libavdevice:${S}/libavfilter:${S}/libavformat:${S}/libavutil" \
+		emake fate
+}
diff --git a/media-video/mplayer/Manifest b/media-video/mplayer/Manifest
index 235bde692f22..0cc373b72906 100644
--- a/media-video/mplayer/Manifest
+++ b/media-video/mplayer/Manifest
@@ -1,5 +1,5 @@
 -----BEGIN PGP SIGNED MESSAGE-----
-Hash: SHA512
+Hash: SHA1
 
 AUX dump_ffmpeg.sh 2494 RMD160 49af8d85dd18122496f32035864e0d87d6446140 SHA1 ca108f8ef69ff16e42faadaa0a6c64deed445d3e SHA256 1f29ad94e1910baba6183a40b8066df2c989f63cbd48f78dc4c6f3e3ccbde8e4
 AUX mplayer-1.0_rc4_p20110322-gcc46.patch 657 RMD160 a327aa565f55102be2d6f73f12e08862418023e9 SHA1 560e41e7c5c147e8656ec0216f4272e1421e887c SHA256 4c57d5c4c79db87796b6b1b4a485f4d0a8ed95f3ae71040592a0bd5f3dc070b2
@@ -11,26 +11,18 @@ DIST font-arial-iso-8859-1.tar.bz2 234242 RMD160 666697cd5efd9387057a898c714175e
 DIST font-arial-iso-8859-2.tar.bz2 222208 RMD160 562d4d92c4f5f3d537340fde3ad8d1495ac41acb SHA1 7b99bbe0e9ba89a57eccbea8f93c453c4f268181 SHA256 71debfc960007c2f6242dfc91e8b1c005b30a99e129aeb00ab8c03f4371b41c1
 DIST mplayer-1.0_rc4_p20110322.tar.xz 8323532 RMD160 7082c95fa20cb7e3d491546ae08a4dfafdc17d09 SHA1 3f60cf0ce8c910e3628e425167cb6a46bb4a29a3 SHA256 addaae78cfd7f8cb950370b3b43d82c2f8170830ccc1046b98726d34f3958bf5
 DIST mplayer-1.0_rc4_p20111215.tar.xz 5209748 RMD160 294a0a6aaf773c0c59e772e059541a315b8134dd SHA1 69f46ffe5b26f1b30a4afbf66bae42f033fca199 SHA256 edb23cae8c49cace3ecb303b6d66490e9a143c5d2d9db803f9ec1bbbbb874635
+DIST mplayer-1.0_rc4_p20120105.tar.xz 5212728 RMD160 53511facf6fac5b7923a6952d356f2e5a8cd232b SHA1 d6631a7ce2771df109b84d184bb5900a778137ae SHA256 2967a4ecbfbb1661db199368167460a61f7d78d74b05e1152f30cfadd12e8242
 EBUILD mplayer-1.0_rc4_p20110322-r1.ebuild 20381 RMD160 19bc9b09ce7902b4a7b16d5b5bd2215dc07a7f1e SHA1 08e9ca9249683695feab78ca3644dcfa1cc586b8 SHA256 1322ed59489cec383d7dac04c752cd083132c21711183e5bc02d70b2a525ab94
 EBUILD mplayer-1.0_rc4_p20111215.ebuild 19483 RMD160 a9ab1ecb51f1c6535793726a8aebbc31285e59a1 SHA1 acbddba711723cc1f725ec5d706444622b6ad547 SHA256 7d02da4cd49e6097cba15204570d507ab09d6f4e2e1270eb749327b53650889d
+EBUILD mplayer-1.0_rc4_p20120105.ebuild 17710 RMD160 67be98e8b2ff9b12e3b2cec11d59a2dfcdbb09ab SHA1 bd573c7d623910fdcc57636ced8ce46fc1717ae8 SHA256 6d2135854130be9f5dfeae100064cc638d2e8c3a6261d325dd83a8dec7fa1f92
 EBUILD mplayer-9999.ebuild 17741 RMD160 0a6e26122ef4f7f0b4d65fef9f4d718348834083 SHA1 e0732891b625cfc0cedc19c76b056d80d105bdf9 SHA256 076f9d22322a2796e4351c22c9776bcedc2154ebd61cbd31796e28929e9c2dc6
-MISC ChangeLog 38763 RMD160 750720ac540ff5bf84f595fbf5fdd790d4bcc76b SHA1 f95c5a9ff2cb8f1e13d3a51769e7dfd63e58861f SHA256 ef2e310bc0b81526f23fe309e54d6f57eca70b8b6a519fa44c82e0bffe18e6a2
+MISC ChangeLog 38986 RMD160 0ddb9e1f0b7838313c0555c5b3c3ad2cb7ad0f14 SHA1 eb99c504164a366701efa32d91689ec7b8d9054d SHA256 6bcfe92cf3ba3bd9dcbd9e3237030b03d8a05d810f895b707a9c536764327fe6
 MISC ChangeLog-2008 107064 RMD160 146604862227a837d1f463a96af6fe94d17421bf SHA1 5a18c910edcf540877f3b803fc85a9b74b503dd2 SHA256 d9949e0e21fd6fd00f1417201455ee399240ef1010dcf56611ac0fc1f6f9505b
 MISC metadata.xml 3737 RMD160 7e18b891f225227f4ecad678e423777f5dd908a7 SHA1 daf40e426abbf0306e2ebeca72ebe54546d81e46 SHA256 dd83a6946f62cbeb84b0e65d2ba6289638d632b80a690714595a44aa3cf86c1a
 -----BEGIN PGP SIGNATURE-----
-Version: GnuPG v2.0.17 (GNU/Linux)
+Version: GnuPG v2.0.18 (GNU/Linux)
 
-iQIcBAEBCgAGBQJPAdN4AAoJEEb+UGWnxTyHLdwQAJryr/wrk5ar6vYeEEE8i2k8
-txbB/s0NJJzyxGxJvDASZ+Li/0F7uRx6i62j6KBYZ+PFERn/XHtuM+cuKq4bGIXY
-kYCRwyhV/M0GBRRNRcWI4akkfNED2U2ryeC9dVcL/pAxRaVQcWmaF1nHvWSJ3HgT
-tsCHuaT9FozTgMPMOUfUoeduJxVLRzcfm2Kag0VrDdxuZRXr/5mJRghaoCX8sU5b
-fnD2I5Da0/uRwmDxVjZXcQJ18tA6x96Tk0V9gtpEnf66GdQBiUC01AKsiEdVTaC5
-7fclo9e+FHmkDt3IjTtwltuLRrQbByZ4kr12xOz5HZUZjm5SBd+RBf6S7/vIYKbH
-QPjOXcDqaEU8mnDBHjdhzsDCcsT4NfXyY7FkiCwt8EB0x+/bSWWlM5R1v0flIrnS
-IOh/UkxYXzDmhSrmZQ7NklZB8FlpYJoSrzDk8bXIfx5rB73mWCo9S2QPZOKE4jb1
-NRTaGq0d1+vvkfsTS2dR5pDjD/2JE8YX3u+CHk4F+7RnHtd+TW2yx5FB55uucUu8
-+a/ZOStHTqJIrpD3a1xZqgn2f2m/3vbiv0NotP8emhWfPfx555ysIa4wLtl0fAIy
-WL5NzmVGGgdMi0Ze8heBLw/DEf8ZJ5mAu0tLKtzSj8Ap0Az8TPZU7sy1yUOGzmUs
-FtQo6DVj8PF40rs/qFw0
-=iC4k
+iEYEARECAAYFAk8FsCAACgkQvFcC4BYPU0pNYQCgmTXZjfyNABVfyDiHDhpyVQlB
+LL0AnjaBgb6jqyby0n+bDhS0YLSs4hjx
+=ebJE
 -----END PGP SIGNATURE-----