Add sys-auth/sssd, bug #321875

Package-Manager: portage-2.1.10.10/cvs/Linux x86_64

4 files changed, 144 insertions, 0 deletions

diff --git a/sys-auth/sssd/ChangeLog b/sys-auth/sssd/ChangeLog
new file mode 100644
index 000000000000..be54a7a83b80
--- /dev/null
+++ b/sys-auth/sssd/ChangeLog
@@ -0,0 +1,11 @@
+# ChangeLog for sys-auth/sssd
+# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sys-auth/sssd/ChangeLog,v 1.1 2011/08/14 21:31:24 maksbotan Exp $
+
+*sssd-1.5.12 (14 Aug 2011)
+
+  14 Aug 2011; <maks@gentoo.org> +sssd-1.5.12.ebuild, +metadata.xml:
+  Add sssd-1.5.12, 1.6.0 is not yet considered ready by ebuild author. Thanks
+  to
+  slepnoga, bug #321875
+
diff --git a/sys-auth/sssd/Manifest b/sys-auth/sssd/Manifest
new file mode 100644
index 000000000000..1f201439eb55
--- /dev/null
+++ b/sys-auth/sssd/Manifest
@@ -0,0 +1,4 @@
+DIST sssd-1.5.12.tar.gz 2835872 RMD160 d675486ad6deab56d903b2ae809b057ba7fb9da8 SHA1 ddfe31e11dbce931e7b8e58c4119780ea227169b SHA256 703b59f1ec575c322457bcad6c1579f34aedc6ea2e29e508739405b26034d3ca
+EBUILD sssd-1.5.12.ebuild 2846 RMD160 ececa61bb6f0b73ca7f414387526b45a0c071d72 SHA1 0a649fe9e4fee413b9a7ec6fe0b2d0b98c24a382 SHA256 a1c793e38341013fbf070ff0ca36fe572dc3dcbab343b07839b2e6ffdf741fed
+MISC ChangeLog 407 RMD160 b75c3bc5645849ea0f1ffc89a2ccd37a7a16e434 SHA1 0ef182bd5dc72a98de22df9e94a24f753a83cdba SHA256 27a8d93643806b55924cbe2195bcbec9481f953c5f44a0d07af2b262658593e4
+MISC metadata.xml 525 RMD160 adfa1acd8ee0124b53554e5389fbf8f5d2c7fd82 SHA1 fefd5ef93f7712df22aa7ea218e11edf88482714 SHA256 998718cda36ef8f9df921ce8dae7c79275b86461968dccf666f715da1d34ce64
diff --git a/sys-auth/sssd/metadata.xml b/sys-auth/sssd/metadata.xml
new file mode 100644
index 000000000000..17e83ae6c0e9
--- /dev/null
+++ b/sys-auth/sssd/metadata.xml
@@ -0,0 +1,16 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+<herd>no-herd</herd>
+<maintainer>
+	<email>spamslepnoga@inbox.ru</email>
+</maintainer>
+<maintainer>
+	<email>maksbotan@gentoo.org</email>
+</maintainer>
+<use>
+	<flag name="locator">Install sssd's Kerberos plugin</flag>
+	<flag name="logrotate">Install logrotate.d file</flag>
+	<flag name="openssl">Enable <pkg>dev-libs/openssl</pkg> support instead of <pkg>dev-libs/nss</pkg></flag>
+</use>
+</pkgmetadata>
diff --git a/sys-auth/sssd/sssd-1.5.12.ebuild b/sys-auth/sssd/sssd-1.5.12.ebuild
new file mode 100644
index 000000000000..71b1727aa05b
--- /dev/null
+++ b/sys-auth/sssd/sssd-1.5.12.ebuild
@@ -0,0 +1,113 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-auth/sssd/sssd-1.5.12.ebuild,v 1.1 2011/08/14 21:31:24 maksbotan Exp $
+
+EAPI=3
+
+PYTHON_DEPEND="python? 2:2.6"
+#RESTRICT="userpriv"
+
+inherit python multilib pam linux-info autotools-utils
+
+DESCRIPTION="System Security Services Daemon provides access to identity and authentication"
+HOMEPAGE="http://fedorahosted.org/sssd/"
+SRC_URI="http://fedorahosted.org/released/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc +locator logrotate nls openssl python selinux static-libs test"
+
+COMMON_DEP="virtual/pam
+	dev-libs/popt
+	>=dev-libs/libunistring-0.9.3
+	>=dev-libs/ding-libs-0.1.2
+	>=sys-libs/talloc-2.0
+	sys-libs/tdb
+	sys-libs/tevent
+	sys-libs/ldb
+	>=net-nds/openldap-2.4.19
+	dev-libs/libpcre
+	>=app-crypt/mit-krb5-1.9.1
+	>=net-dns/c-ares-1.7.4
+	openssl? ( dev-libs/openssl )
+	!openssl? ( >=dev-libs/nss-3.12.9 )
+	selinux? ( >=sys-libs/libselinux-2.0.94 >=sys-libs/libsemanage-2.0.45 )
+	net-dns/bind-tools
+	dev-libs/cyrus-sasl
+	sys-apps/dbus
+	>=sys-devel/gettext-0.17
+	virtual/libintl
+	dev-libs/libnl"
+
+RDEPEND="${COMMON_DEP}"
+DEPEND="${COMMON_DEP}
+	test? ( dev-libs/check )
+	>=dev-libs/libxslt-1.1.26
+	app-text/docbook-xml-dtd:4.4
+	doc? ( app-doc/doxygen )"
+
+CONFIG_CHECK="~KEYS"
+AUTOTOOLS_IN_SOURCE_BUILD=1
+
+pkg_setup(){
+	python_set_active_version 2
+	python_need_rebuild
+	linux-info_pkg_setup
+}
+
+src_configure(){
+	local myeconfargs=(
+		--localstatedir="${EPREFIX}"/var
+		--enable-nsslibdir="${EPREFIX}"/$(get_libdir)
+		--enable-pammoddir="${EPREFIX}"/$(getpam_mod_dir)
+		$(use_with selinux)
+		$(use_with selinux semanage)
+		--with-libnl
+		--with-ldb-lib-dir="${EPREFIX}"/$(get_libdir)/ldb/modules/
+		$(use_with python python-bindings)
+		--without-nscd
+		$(use_enable locator krb5-locator-plugin)
+		$(use_enable openssl crypto)
+		$(use_enable nls ) )
+
+	autotools-utils_src_configure
+}
+
+src_install(){
+	autotools-utils_src_install
+
+	rm  "${ED}/$(get_libdir)/"libnss_sss.la || die
+
+	insinto /etc/sssd
+	insopts -m600
+	doins "${S}"/src/examples/sssd.conf
+
+	if use logrotate; then
+		insinto /etc/logrotate.d
+		insopts -m644
+		newins "${S}"/src/examples/logrotate sssd
+	fi
+
+	if use python; then
+		python_clean_installation_image
+		python_convert_shebangs 2 "${ED}$(python_get_sitedir)/"*.py
+	fi
+}
+
+src_test() {
+	autotools-utils_src_test
+}
+
+pkg_postinst(){
+	elog "You must set up sssd.conf (default installed into /etc/sssd)"
+	elog "and (optionally) configuration in /etc/pam.d in order to use SSSD"
+	elog "features. Please see howto in	http://fedorahosted.org/sssd/wiki/HOWTO_Configure_1_0_2"
+
+	use python && python_need_rebuild
+	use python && python_mod_optimize SSSDConfig.py ipachangeconf.py
+}
+
+pkg_postrm() {
+	use python && python_mod_cleanup SSSDConfig.py ipachangeconf.py
+}