Merge updates from master

3 files changed, 91 insertions, 1 deletions

diff --git a/app-text/tesseract/tesseract-5.4.1.ebuild b/app-text/tesseract/tesseract-5.4.1.ebuild
index d4438214a13d..e44487d85747 100644
--- a/app-text/tesseract/tesseract-5.4.1.ebuild
+++ b/app-text/tesseract/tesseract-5.4.1.ebuild
@@ -11,7 +11,7 @@ SRC_URI="https://github.com/tesseract-ocr/${PN}/archive/${PV}.tar.gz -> ${P}.tar
 
 LICENSE="Apache-2.0"
 SLOT="0/5"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+KEYWORDS="~alpha amd64 arm ~arm64 ~mips ppc ppc64 ~riscv ~sparc x86"
 IUSE="doc float32 jpeg openmp png static-libs tiff training webp"
 
 COMMON_DEPEND=">=media-libs/leptonica-1.74:=[${MULTILIB_USEDEP},zlib,tiff?,jpeg?,png?,webp?]
diff --git a/media-libs/harfbuzz/Manifest b/media-libs/harfbuzz/Manifest
index 3d1eb2933920..829e47532b76 100644
--- a/media-libs/harfbuzz/Manifest
+++ b/media-libs/harfbuzz/Manifest
@@ -1,3 +1,4 @@
 DIST harfbuzz-10.0.1.tar.xz 17914712 BLAKE2B d1506658646a589c772d8efec1f40095ff8097f5d34c6498aa848027e71583c511d337ceea5005a4f5ce08f28c2d952fd3007383d701e957fb0c923edeba9466 SHA512 3fb7dda6e51496337698d46cebe623f678a4e5b0f006be6e1309143a82408a362c149812477e083e14811a5cba565d76eb2c0804f5e1bbea7e1bf83678176048
+DIST harfbuzz-10.1.0.tar.xz 17922136 BLAKE2B 7d78e31d045b984d8d1a8b1d1f8f282ff9b7dc748ffd65355266266e75064b14eb94ec6b1418e208ebb0fffb99ef174d1978ab14f0c318c1112c2d8005285979 SHA512 14b0e8fd417af9c78f36e532e3737c163902b85837be1028a8fd569508639b87afeb56f70a2313ba2f0f6d4b72bb6cee0bf50fb333dfc503c713e4d9cd86e9c3
 DIST harfbuzz-8.5.0.tar.xz 19468172 BLAKE2B f598d7de953834499d1ab36c0fc9d95099fd7e99b87f630e1527aaa39deb2d339b9f3caaea3643238c6c1b321557f794f273929950b54fe9de2faa430d77855a SHA512 d5762f77b0913792d34596e6f3adb98ab693e2ef928396f997ca2e647ca7cad13fdd204fa15b49e2f7c33320ff210d7f078215d5765c9365571458b919a4f10c
 DIST harfbuzz-9.0.0.tar.xz 17895360 BLAKE2B fd35c41d25e77c96b1fc760b8ca0ffd1ac8f3382b51991bb28797d55c2171bf0700ac65266996bf5cab82b8e9c835c2fad9c8374d9c60d2a361c924d805afbf6 SHA512 2700b560727d9c4440ad9c74a170b857f20f9e553e5d98b0c4bcf086a25ba644149d7c89009a41d964af7a924efcc486da4dcbfa5cc4d47f9f10e9b6b8c689af
diff --git a/media-libs/harfbuzz/harfbuzz-10.1.0.ebuild b/media-libs/harfbuzz/harfbuzz-10.1.0.ebuild
new file mode 100644
index 000000000000..7214ae683e59
--- /dev/null
+++ b/media-libs/harfbuzz/harfbuzz-10.1.0.ebuild
@@ -0,0 +1,89 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit flag-o-matic meson-multilib python-any-r1 xdg-utils
+
+DESCRIPTION="An OpenType text shaping engine"
+HOMEPAGE="https://www.freedesktop.org/wiki/Software/HarfBuzz"
+
+if [[ ${PV} == 9999 ]] ; then
+	EGIT_REPO_URI="https://github.com/harfbuzz/harfbuzz.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/harfbuzz/harfbuzz/releases/download/${PV}/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
+fi
+
+LICENSE="Old-MIT ISC icu"
+# 0.9.18 introduced the harfbuzz-icu split; bug #472416
+# 3.0.0 dropped some unstable APIs; bug #813705
+# 6.0.0 changed libharfbuzz-subset.so ABI
+SLOT="0/6.0.0"
+
+IUSE="+cairo debug doc experimental +glib +graphite icu +introspection test +truetype"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="introspection? ( glib )"
+
+RDEPEND="
+	cairo? ( x11-libs/cairo:=[${MULTILIB_USEDEP}] )
+	glib? ( >=dev-libs/glib-2.38:2[${MULTILIB_USEDEP}] )
+	graphite? ( >=media-gfx/graphite2-1.2.1:=[${MULTILIB_USEDEP}] )
+	icu? ( >=dev-libs/icu-51.2-r1:=[${MULTILIB_USEDEP}] )
+	introspection? ( >=dev-libs/gobject-introspection-1.34:= )
+	truetype? ( >=media-libs/freetype-2.5.0.1:2=[${MULTILIB_USEDEP}] )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	${PYTHON_DEPS}
+	virtual/pkgconfig
+	doc? ( dev-util/gtk-doc )
+	introspection? ( dev-util/glib-utils )
+"
+
+src_prepare() {
+	default
+
+	xdg_environment_reset
+
+	# bug #790359
+	filter-flags -fexceptions -fthreadsafe-statics
+
+	if ! use debug ; then
+		append-cppflags -DHB_NDEBUG
+	fi
+}
+
+multilib_src_configure() {
+	# harfbuzz-gobject only used for introspection, bug #535852
+	local emesonargs=(
+		-Dcoretext=disabled
+		-Dchafa=disabled
+		-Dwasm=disabled
+
+		$(meson_feature cairo)
+		$(meson_feature glib)
+		$(meson_feature graphite graphite2)
+		$(meson_feature icu)
+		$(meson_feature introspection gobject)
+		$(meson_feature test tests)
+		$(meson_feature truetype freetype)
+
+		$(meson_native_use_feature doc docs)
+		$(meson_native_use_feature introspection)
+		# Breaks building tests..
+		#$(meson_native_use_feature utilities)
+
+		$(meson_use experimental experimental_api)
+	)
+
+	meson_src_configure
+}
+
+multilib_src_test() {
+	# harfbuzz:src / check-static-inits times out on hppa
+	meson_src_test --timeout-multiplier 5
+}