dev-java/jcalendar: rewrite with java-pkg-simple

Signed-off-by: Volkmar W. Pogatzki <gentoo@pogatzki.net>
Closes: https://github.com/gentoo/gentoo/pull/36770/commits/6205b8c861078d4a057e4e2c47978e64f5170fce
Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>

1 files changed, 43 insertions, 0 deletions

diff --git a/dev-java/jcalendar/jcalendar-1.4-r2.ebuild b/dev-java/jcalendar/jcalendar-1.4-r2.ebuild
new file mode 100644
index 000000000000..cc3c29b2f91c
--- /dev/null
+++ b/dev-java/jcalendar/jcalendar-1.4-r2.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+JAVA_PKG_IUSE="doc source"
+
+inherit java-pkg-2 java-pkg-simple
+
+DESCRIPTION="Java date chooser bean for graphically picking a date"
+HOMEPAGE="https://toedter.com/jcalendar/"
+SRC_URI="https://www.toedter.com/download/${P}.zip"
+
+LICENSE="LGPL-2.1"
+SLOT="1.2"
+KEYWORDS="~amd64 ~x86"
+
+BDEPEND="app-arch/unzip"
+
+CP_DEPEND="dev-java/jgoodies-looks:2.6"
+
+DEPEND="
+	${CP_DEPEND}
+	>=virtual/jdk-1.8:*"
+
+RDEPEND="
+	${CP_DEPEND}
+	>=virtual/jre-1.8:*"
+
+JAVA_MAIN_CLASS="com.toedter.calendar.demo.JCalendarDemo"
+JAVA_RESOURCE_DIRS="res"
+JAVA_SRC_DIR="src"
+
+src_prepare() {
+	java-pkg-2_src_prepare
+	java-pkg_clean
+	mkdir -p res/META-INF || die
+	mv src/jcalendar.manifest res/META-INF/MANIFEST.MF || die
+	pushd src > /dev/null || die
+		find com -type f ! -name '*.java' \
+			| xargs cp --parents -t ../res || die
+	popd > /dev/null || die
+}