dev-lang/mercury-extras: version bump

Package-Manager: Portage-2.3.8, Repoman-2.3.1

2 files changed, 201 insertions, 0 deletions

diff --git a/dev-lang/mercury-extras/Manifest b/dev-lang/mercury-extras/Manifest
index 3c743fffd588..326e6ec613e7 100644
--- a/dev-lang/mercury-extras/Manifest
+++ b/dev-lang/mercury-extras/Manifest
@@ -1,4 +1,6 @@
 DIST mercury-extras-13.05.2-gentoo-patchset-3.tar.gz 3538 SHA256 96a041d185778befa98c98b232041738878666a33bd695dbc7d1e2ab9eccca41 SHA512 c151f876768c6b6ab7b46b4e2501569586249f5e185e534ebb5817206ac0844cd081ccae86a26ef85f27eab9d851017393c837728bd194520a549a0a60f738ef WHIRLPOOL 3b8eccd3252027a99a700240a45be2a1dc650055e65a4699ee3f93b8aca39da9057787e576c3e76a48a9134f25cff2c3e7a9ab88c1fc25a6eb2580d1f38ddb42
 DIST mercury-extras-14.01-gentoo-patchset-1.tar.gz 3856 SHA256 2ea27bc699998834298dab3f9c1179681ac528b32f005493cd5027d0dbe52fbc SHA512 c584efd4c7af54d2e8d5af0a63acced118f356527a2bf692262e37366e1018247aac8c1bb8f700f08f8f0a2c95d979e215e3c949ec1dc2994ab40048eb5b253c WHIRLPOOL 4b5169eb5cdd70caa350e562c276a59bfe9eca5fc3d66d10a3e10b6b653d0a41dd18409c1d26a66a20d1cecf31282408fcbf2d3e5321f16a57f095dd4907165f
+DIST mercury-extras-14.01.1-gentoo-patchset-0.tar.gz 3688 SHA256 4aa4d2f1e1b7637b8df0dfba1ac6e46bf0314c06645ed3197452c615e84d6b66 SHA512 02781ca23e72920c932067f7270d06e45909728133588c181b94f7b7580f841b4b0f1dd523e0c100350b191e5b28a7d1f10ad51fdffe2dcb02ff78cd5a906e3b WHIRLPOOL 834923a00ea98ae4d28cfd451e5d6e0638adac99c92a85d173210b87e357cc8419a3a80cf6f11242ce548b3c4b3658841da226600df73821b57c4192766e0cc3
 DIST mercury-srcdist-13.05.2.tar.gz 53847394 SHA256 8491cf419b996a315bf8664154dd91aed940274ded98e3aded733dbe1939f95f SHA512 2298804d3a04bca6be4bd3046643c7c0d0b22c447423017869cd9bf3a4fb6ec9fd29b5d8e1a386d5d52d07be5cad73608f1fcacf46732a7add93a01dcd199c08 WHIRLPOOL 2a81bebfd4b97b9bb1b0e174025e6050149c8e5f812cd97cbdc41818faa18c15f9494925f1f320682087cc45264bc00db07bef6862afef12317f77cc169a7f86
+DIST mercury-srcdist-14.01.1.tar.gz 52658945 SHA256 98f7cbde7a7425365400feef3e69f1d6a848b25dc56ba959050523d546c4e88b SHA512 a128ef0fd4955abadea32019ec59297ffe32537415f32e9e948cbc1c3439bb40eb09de77569690fb18dd7d6969a2b1141b3ae5baeb87f2627eaa65ad93add92c WHIRLPOOL 7b859eb5c7c1194d63c0aeeeeac3686c57436100b5618ae31a901119a33443363acb80a908a15dfdfa8b61fd9ccb4e552cbb972a3cc735b7a768ee7c9b1b6091
 DIST mercury-srcdist-14.01.tar.gz 52683989 SHA256 4446b7b4eafd35540495ef90ce93b71cb88efa2d744628aee80f76a694aefcc1 SHA512 77f61df64fc150e08f191860f285b97d11a71a52eabc95f660b3c90d88f8ee71d1227f7ab4b8be78be9d4aa3d62a260a874020023e4795da4cfd2e6fefa9965f WHIRLPOOL a7123063590e39ae15222eb59a2c3681ae37bea211967c857eb8725090d342f0aba7a55446529f8608afb9895746581943527b1b3c313c5cbb96f638a3377404
diff --git a/dev-lang/mercury-extras/mercury-extras-14.01.1.ebuild b/dev-lang/mercury-extras/mercury-extras-14.01.1.ebuild
new file mode 100644
index 000000000000..0fb9ffe07f2b
--- /dev/null
+++ b/dev-lang/mercury-extras/mercury-extras-14.01.1.ebuild
@@ -0,0 +1,199 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+
+inherit eutils multilib
+
+PATCHSET_VER="0"
+MY_P=mercury-srcdist-${PV}
+
+DESCRIPTION="Additional libraries and tools that are not part of the Mercury standard library"
+HOMEPAGE="http://www.mercurylang.org/index.html"
+SRC_URI="http://dl.mercurylang.org/release/${MY_P}.tar.gz
+	mirror://gentoo/${P}-gentoo-patchset-${PATCHSET_VER}.tar.gz"
+
+LICENSE="GPL-2 LGPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+IUSE="X cairo examples glut iodbc ncurses odbc opengl ssl tcl tk xml"
+
+RDEPEND="~dev-lang/mercury-${PV}
+	cairo? ( >=x11-libs/cairo-1.10.0 )
+	glut? ( media-libs/freeglut )
+	odbc? ( dev-db/unixODBC )
+	iodbc? ( !odbc? ( dev-db/libiodbc ) )
+	ncurses? ( sys-libs/ncurses:= )
+	opengl? (
+		virtual/opengl
+		virtual/glu
+	)
+	tcl? ( tk? (
+			dev-lang/tcl:0
+			dev-lang/tk:0
+			x11-libs/libX11
+			x11-libs/libXmu
+		)
+	)"
+
+DEPEND="${RDEPEND}"
+
+S="${WORKDIR}"/${MY_P}/extras
+
+mercury_pkgs()
+{
+	echo   "base64
+		cgi
+		complex_numbers
+		dynamic_linking
+		error
+		fixed
+		lex
+		moose
+		posix
+		solver_types/library
+		$(use ncurses && echo curs curses)
+		$(use glut && echo graphics/mercury_glut)
+		$(use opengl && echo graphics/mercury_opengl)
+		$(use tcl && use tk && echo graphics/mercury_tcltk)
+		$(use odbc && echo odbc || use iodbc && echo odbc)
+		$(has_version dev-lang/mercury[trail] && echo references)
+		$(usev xml)"
+}
+
+src_prepare() {
+	cd "${WORKDIR}"
+
+	EPATCH_FORCE=yes
+	EPATCH_SUFFIX=patch
+	if [[ -d "${WORKDIR}"/${PV} ]] ; then
+		epatch "${WORKDIR}"/${PV}
+	fi
+
+	cd "${S}"
+	if use odbc; then
+		cp odbc/Mmakefile.odbc odbc/Mmakefile
+	elif use iodbc; then
+		cp odbc/Mmakefile.iodbc odbc/Mmakefile
+	fi
+}
+
+src_compile() {
+	local MERCURY_PKGS="$(mercury_pkgs)"
+
+	# Mercury dependency generation must be run single-threaded
+	mmake -j1 \
+		SUBDIRS="${MERCURY_PKGS}" \
+		depend || die "mmake depend failed"
+
+	# Compiling Mercury submodules is not thread-safe
+	mmake -j1 \
+		SUBDIRS="${MERCURY_PKGS}" \
+		EXTRA_MLFLAGS=--no-strip \
+		EXTRA_CFLAGS="${CFLAGS}" \
+		EXTRA_LDFLAGS="${LDFLAGS}" \
+		EXTRA_LD_LIBFLAGS="${LDFLAGS}" \
+		|| die "mmake failed"
+
+	if use cairo; then
+		cd "${S}"/graphics/mercury_cairo
+		mmc --make libmercury_cairo \
+			|| die "mmc --make libmercury_cairo failed"
+	fi
+}
+
+src_install() {
+	local MERCURY_PKGS="$(mercury_pkgs)"
+
+	# Compiling Mercury submodules is not thread-safe
+	mmake -j1 \
+		SUBDIRS="${MERCURY_PKGS}" \
+		EXTRA_MLFLAGS=--no-strip \
+		EXTRA_CFLAGS="${CFLAGS}" \
+		EXTRA_LDFLAGS="${LDFLAGS}" \
+		EXTRA_LD_LIBFLAGS="${LDFLAGS}" \
+		DESTDIR="${D}" \
+		INSTALL_PREFIX="${D}"/usr \
+		install || die "mmake install failed"
+
+	if use cairo; then
+		cd "${S}"/graphics/mercury_cairo
+		INSTALL_PREFIX="${D}"/usr \
+		mmc --make libmercury_cairo.install \
+			|| die "mmc --make libmercury_cairo.install failed"
+	fi
+
+	find "${D}"/usr/$(get_libdir)/mercury -type l | xargs rm
+
+	cd "${S}"
+	if use examples; then
+		insinto /usr/share/doc/${PF}/samples/base64
+		doins base64/*.m || die
+
+		insinto /usr/share/doc/${PF}/samples/complex_numbers
+		doins complex_numbers/samples/* || die
+
+		insinto /usr/share/doc/${PF}/samples/dynamic_linking
+		doins dynamic_linking/hello.m || die
+
+		insinto /usr/share/doc/${PF}/samples/error
+		doins error/* || die
+
+		insinto /usr/share/doc/${PF}/samples/fixed
+		doins fixed/*.m || die
+
+		insinto /usr/share/doc/${PF}/samples/gator
+		doins -r gator/* || die
+
+		insinto /usr/share/doc/${PF}/samples/lex
+		doins lex/samples/* || die
+
+		insinto /usr/share/doc/${PF}/samples/log4m
+		doins log4m/*.m || die
+
+		insinto /usr/share/doc/${PF}/samples/monte
+		doins monte/*.m || die
+
+		insinto /usr/share/doc/${PF}/samples/moose
+		doins moose/samples/* || die
+
+		insinto /usr/share/doc/${PF}/samples/net
+		doins net/*.m || die
+
+		if use ncurses; then
+			insinto /usr/share/doc/${PF}/samples/curs
+			doins curs/samples/* || die
+
+			insinto /usr/share/doc/${PF}/samples/curses
+			doins curses/sample/* || die
+		fi
+
+		if use X; then
+			insinto /usr/share/doc/${PF}/samples/graphics
+			doins graphics/easyx/samples/*.m || die
+		fi
+
+		if use glut && use opengl; then
+			insinto /usr/share/doc/${PF}/samples/graphics
+			doins graphics/samples/calc/* || die
+			doins graphics/samples/gears/* || die
+			doins graphics/samples/maze/* || die
+			doins graphics/samples/pent/* || die
+		fi
+
+		if use opengl && use tcl && use tk; then
+			insinto /usr/share/doc/${PF}/samples/graphics
+			doins graphics/samples/pent/*.m || die
+		fi
+
+		if use ssl; then
+			insinto /usr/share/doc/${PF}/samples/mopenssl
+			doins mopenssl/*.m || die
+		fi
+
+		ecvs_clean
+	fi
+
+	dodoc README || die
+}