dev-lang/yasm: drop python support

Bug: https://bugs.gentoo.org/702364
Signed-off-by: Mike Gilbert <floppym@gentoo.org>

2 files changed, 74 insertions, 21 deletions

diff --git a/dev-lang/yasm/yasm-1.3.0-r1.ebuild b/dev-lang/yasm/yasm-1.3.0-r1.ebuild
new file mode 100644
index 000000000000..ffd88e2bc667
--- /dev/null
+++ b/dev-lang/yasm/yasm-1.3.0-r1.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs
+
+if [[ ${PV} == 9999* ]] ; then
+	EGIT_REPO_URI="https://github.com/yasm/yasm.git"
+	inherit autotools git-r3
+else
+	SRC_URI="http://www.tortall.net/projects/yasm/releases/${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm64 ~x86 ~amd64-linux ~x86-linux ~x64-macos ~x86-macos ~x64-solaris ~x86-solaris"
+fi
+
+DESCRIPTION="An assembler for x86 and x86_64 instruction sets"
+HOMEPAGE="http://yasm.tortall.net/"
+
+LICENSE="BSD-2 BSD || ( Artistic GPL-2 LGPL-2 )"
+SLOT="0"
+IUSE="nls"
+
+BDEPEND="
+	nls? ( sys-devel/gettext )
+"
+DEPEND="
+	nls? ( virtual/libintl )
+"
+RDEPEND="${DEPEND}
+"
+
+if [[ ${PV} == 9999* ]]; then
+	BDEPEND+="
+		app-text/xmlto
+		app-text/docbook-xml-dtd:4.1.2
+		dev-lang/python
+	"
+fi
+
+src_prepare() {
+	default
+
+	if [[ ${PV} == 9999* ]]; then
+		eautoreconf
+		python modules/arch/x86/gen_x86_insn.py || die
+	fi
+}
+
+src_configure() {
+	local myconf=(
+		CC_FOR_BUILD="$(tc-getBUILD_CC)"
+		CCLD_FOR_BUILD="$(tc-getBUILD_CC)"
+		--disable-warnerror
+		--disable-python
+		--disable-python-bindings
+		$(use_enable nls)
+	)
+
+	econf "${myconf[@]}"
+}
+
+src_test() {
+	# https://bugs.gentoo.org/718870
+	emake -j1 check
+}
diff --git a/dev-lang/yasm/yasm-9999.ebuild b/dev-lang/yasm/yasm-9999.ebuild
index ccd86bc00909..ffd88e2bc667 100644
--- a/dev-lang/yasm/yasm-9999.ebuild
+++ b/dev-lang/yasm/yasm-9999.ebuild
@@ -2,16 +2,15 @@
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
-PYTHON_COMPAT=( python2_7 )
 
-inherit python-single-r1 toolchain-funcs
+inherit toolchain-funcs
 
 if [[ ${PV} == 9999* ]] ; then
 	EGIT_REPO_URI="https://github.com/yasm/yasm.git"
 	inherit autotools git-r3
 else
 	SRC_URI="http://www.tortall.net/projects/yasm/releases/${P}.tar.gz"
-	KEYWORDS="-* ~amd64 ~x86 ~amd64-linux ~x86-linux ~x64-macos ~x86-macos ~x86-solaris"
+	KEYWORDS="~amd64 ~arm64 ~x86 ~amd64-linux ~x86-linux ~x64-macos ~x86-macos ~x64-solaris ~x86-solaris"
 fi
 
 DESCRIPTION="An assembler for x86 and x86_64 instruction sets"
@@ -19,52 +18,41 @@ HOMEPAGE="http://yasm.tortall.net/"
 
 LICENSE="BSD-2 BSD || ( Artistic GPL-2 LGPL-2 )"
 SLOT="0"
-IUSE="nls python"
-REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+IUSE="nls"
 
 BDEPEND="
 	nls? ( sys-devel/gettext )
-	python? (
-		${PYTHON_DEPS}
-		$(python_gen_cond_dep '>=dev-python/cython-0.14[${PYTHON_USEDEP}]')
-	)
 "
 DEPEND="
 	nls? ( virtual/libintl )
 "
 RDEPEND="${DEPEND}
-	python? ( ${PYTHON_DEPS} )
 "
 
 if [[ ${PV} == 9999* ]]; then
 	BDEPEND+="
 		app-text/xmlto
 		app-text/docbook-xml-dtd:4.1.2
+		dev-lang/python
 	"
 fi
 
-pkg_setup() {
-	: # Avoid python-single-r1_pkg_setup
-}
-
 src_prepare() {
 	default
 
 	if [[ ${PV} == 9999* ]]; then
 		eautoreconf
-		./modules/arch/x86/gen_x86_insn.py || die
+		python modules/arch/x86/gen_x86_insn.py || die
 	fi
 }
 
 src_configure() {
-	use python && python_setup
-
 	local myconf=(
-		CC_FOR_BUILD=$(tc-getBUILD_CC) \
-		CCLD_FOR_BUILD=$(tc-getBUILD_CC) \
+		CC_FOR_BUILD="$(tc-getBUILD_CC)"
+		CCLD_FOR_BUILD="$(tc-getBUILD_CC)"
 		--disable-warnerror
-		$(use_enable python)
-		$(use_enable python python-bindings)
+		--disable-python
+		--disable-python-bindings
 		$(use_enable nls)
 	)