dev-python/charset_normalizer: Remanifest

Upstream has re-tagged the release with fixed version number.
Remanifest and revbump to force rebuilding against the new tarball.

Closes: https://bugs.gentoo.org/873277
Signed-off-by: Michał Górny <mgorny@gentoo.org>

1 files changed, 36 insertions, 0 deletions

diff --git a/dev-python/charset_normalizer/charset_normalizer-2.1.1-r1.ebuild b/dev-python/charset_normalizer/charset_normalizer-2.1.1-r1.ebuild
new file mode 100644
index 000000000000..07597e4710c7
--- /dev/null
+++ b/dev-python/charset_normalizer/charset_normalizer-2.1.1-r1.ebuild
@@ -0,0 +1,36 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# please keep this ebuild at EAPI 7 -- sys-apps/portage dep
+EAPI=7
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..11} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="The Real First Universal Charset Detector"
+HOMEPAGE="
+	https://pypi.org/project/charset-normalizer/
+	https://github.com/Ousret/charset_normalizer/
+"
+SRC_URI="
+	https://github.com/Ousret/charset_normalizer/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	sed -i -e '/addopts/d' setup.cfg || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+}