kde-apps: Add KDE Applications 18.12.0

Package-Manager: Portage-2.3.52, Repoman-2.3.12
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

1 files changed, 75 insertions, 0 deletions

diff --git a/kde-apps/ark/ark-18.12.0.ebuild b/kde-apps/ark/ark-18.12.0.ebuild
new file mode 100644
index 000000000000..c6f3ec55fd70
--- /dev/null
+++ b/kde-apps/ark/ark-18.12.0.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+KDE_HANDBOOK="forceoptional"
+KDE_TEST="optional"
+VIRTUALX_REQUIRED="test"
+inherit kde5
+
+DESCRIPTION="KDE Archiving tool"
+HOMEPAGE="https://www.kde.org/applications/utilities/ark
+https://utils.kde.org/projects/ark/"
+KEYWORDS="~amd64 ~x86"
+IUSE="bzip2 lzma zip"
+
+RDEPEND="
+	$(add_frameworks_dep karchive)
+	$(add_frameworks_dep kcompletion)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kcrash)
+	$(add_frameworks_dep kdbusaddons)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kiconthemes)
+	$(add_frameworks_dep kio)
+	$(add_frameworks_dep kitemmodels)
+	$(add_frameworks_dep kjobwidgets)
+	$(add_frameworks_dep kparts)
+	$(add_frameworks_dep kpty)
+	$(add_frameworks_dep kservice)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_frameworks_dep kxmlgui)
+	$(add_qt_dep qtdbus)
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtwidgets)
+	app-arch/libarchive:=[bzip2?,lzma?,zlib]
+	sys-libs/zlib
+	zip? ( >=dev-libs/libzip-1.2.0:= )
+"
+DEPEND="${RDEPEND}
+	$(add_qt_dep qtconcurrent)
+	sys-devel/gettext
+"
+
+# bug #560548, last checked with 16.04.1
+RESTRICT+=" test"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_find_package bzip2 BZip2)
+		$(cmake-utils_use_find_package lzma LibLZMA)
+		$(cmake-utils_use_find_package zip LibZip)
+	)
+
+	kde5_src_configure
+}
+
+pkg_postinst() {
+	kde5_pkg_postinst
+
+	if ! has_version app-arch/unar && ! has_version app-arch/unrar; then
+		elog "For extracting rar archives, install app-arch/unar (free) or app-arch/unrar (non-free)."
+	fi
+
+	has_version app-arch/rar || \
+		elog "For creating rar archives, installing app-arch/rar is required."
+
+	has_version app-arch/p7zip || \
+		elog "For handling 7-Zip archives, install app-arch/p7zip."
+
+	has_version app-arch/lrzip || \
+		elog "For handling lrz archives, install app-arch/lrzip."
+}