mate-base/mate-session-manager: Set IUSE="+xtrans", #621358

Include warning in metadata about rammifications of disabling this default flag

Package-Manager: Portage-2.3.6, Repoman-2.3.2

2 files changed, 87 insertions, 1 deletions

diff --git a/mate-base/mate-session-manager/mate-session-manager-1.18.0-r1.ebuild b/mate-base/mate-session-manager/mate-session-manager-1.18.0-r1.ebuild
new file mode 100644
index 000000000000..750c70fd689c
--- /dev/null
+++ b/mate-base/mate-session-manager/mate-session-manager-1.18.0-r1.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit mate
+
+if [[ ${PV} != 9999 ]]; then
+	KEYWORDS="~amd64 ~arm ~x86"
+fi
+
+DESCRIPTION="MATE session manager"
+HOMEPAGE="http://mate-desktop.org/"
+
+LICENSE="GPL-2 LGPL-2 FDL-1.1"
+SLOT="0"
+
+IUSE="debug elibc_FreeBSD gnome-keyring ipv6 systemd +xtrans"
+
+# x11-misc/xdg-user-dirs{,-gtk} are needed to create the various XDG_*_DIRs, and
+# create .config/user-dirs.dirs which is read by glib to get G_USER_DIRECTORY_*
+# xdg-user-dirs-update is run during login (see 10-user-dirs-update-gnome below).
+
+COMMON_DEPEND=">=dev-libs/dbus-glib-0.76
+	>=dev-libs/glib-2.36:2
+	dev-libs/libxslt
+	sys-apps/dbus
+	x11-libs/gdk-pixbuf:2
+	>=x11-libs/gtk+-3.14:3
+	x11-libs/libICE
+	x11-libs/libSM
+	x11-libs/libX11
+	x11-libs/libXau
+	x11-libs/libXext
+	x11-libs/libXrender
+	x11-libs/libXtst
+	x11-libs/pango
+	virtual/libintl
+	elibc_FreeBSD? ( dev-libs/libexecinfo )
+	systemd? ( sys-apps/systemd )
+	!systemd? ( >=sys-auth/consolekit-0.9.2 )
+	xtrans? ( x11-libs/xtrans )"
+
+RDEPEND="${COMMON_DEPEND}
+	x11-apps/xdpyinfo
+	x11-misc/xdg-user-dirs
+	x11-misc/xdg-user-dirs-gtk
+	gnome-keyring? ( gnome-base/gnome-keyring )"
+
+DEPEND="${COMMON_DEPEND}
+	>=dev-util/intltool-0.40:*
+	>=dev-lang/perl-5
+	>=sys-devel/gettext-0.10.40:*
+	virtual/pkgconfig:*
+	!<gnome-base/gdm-2.20.4"
+
+MATE_FORCE_AUTORECONF=true
+
+src_configure() {
+	mate_src_configure \
+		--docdir="${EPREFIX}/usr/share/doc/${PF}" \
+		$(use_with systemd) \
+		$(use_with xtrans)  \
+		$(use_enable debug) \
+		$(use_enable ipv6)
+}
+
+src_install() {
+	mate_src_install
+
+	dodir /etc/X11/Sessions/
+	exeinto /etc/X11/Sessions/
+	doexe "${FILESDIR}"/MATE
+
+	dodir /usr/share/mate/applications/
+	insinto /usr/share/mate/applications/
+	doins "${FILESDIR}"/defaults.list
+
+	dodir /etc/X11/xinit/xinitrc.d/
+	exeinto /etc/X11/xinit/xinitrc.d/
+	doexe "${FILESDIR}"/15-xdg-data-mate
+
+	# This should be done in MATE too, see Gentoo bug #270852
+	doexe "${FILESDIR}"/10-user-dirs-update-mate
+}
diff --git a/mate-base/mate-session-manager/metadata.xml b/mate-base/mate-session-manager/metadata.xml
index 2a87982eeb67..f930f98b8909 100644
--- a/mate-base/mate-session-manager/metadata.xml
+++ b/mate-base/mate-session-manager/metadata.xml
@@ -7,7 +7,8 @@
     </maintainer>
 	<use>
 		<flag name="gtk3">Build with GTK+3 instead of GTK+2</flag>
-		<flag name="xtrans">Build with Xtrans support</flag>
+		<flag name="xtrans">Build with Xtrans support; 
+		WARNING: Disabling this flag will result in ICE binding on all interfaces</flag>
 	</use>
     <upstream>
         <remote-id type="github">mate-desktop/mate-session-manager</remote-id>