blob: 48998431ea985cc843d48a5412b5561310cd372f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
|
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=6
PYTHON_COMPAT=( python{2_7,3_{4,5,6}} )
inherit readme.gentoo-r1 distutils-r1
DESCRIPTION="Python library and command line tool for configuring a YubiKey"
HOMEPAGE="https://developers.yubico.com/yubikey-manager/"
SRC_URI="https://github.com/Yubico/${PN}/archive/${P}.tar.gz"
S="${WORKDIR}/${PN}-${P}" # <- need this only for github-based SRC_URI
# Here's the alternative SRC_URI, though tarball contents may differ
# See: https://github.com/Yubico/yubikey-manager/issues/217
# SRC_URI="https://developers.yubico.com/${PN}/Releases/${P}.tar.gz"
LICENSE="BSD-2"
SLOT="0"
KEYWORDS="amd64 x86"
IUSE="test"
RDEPEND="
dev-python/click[${PYTHON_USEDEP}]
dev-python/cryptography[${PYTHON_USEDEP}]
$(python_gen_cond_dep 'dev-python/enum34[${PYTHON_USEDEP}]' python2_7)
dev-python/fido2[${PYTHON_USEDEP}]
dev-python/pyopenssl[${PYTHON_USEDEP}]
dev-python/pyscard[${PYTHON_USEDEP}]
dev-python/pyusb[${PYTHON_USEDEP}]
dev-python/six[${PYTHON_USEDEP}]
>=sys-auth/ykpers-1.19.0
"
DEPEND="
dev-python/setuptools[${PYTHON_USEDEP}]
test? (
${RDEPEND}
$(python_gen_cond_dep 'dev-python/mock[${PYTHON_USEDEP}]' 'python2_7')
)
"
python_test() {
esetup.py test
}
python_install_all() {
local DOC_CONTENTS
distutils-r1_python_install_all
DOC_CONTENTS="
The 'openpgp' command may require the package 'app-crypt/ccid'
to be installed on the system. Furthermore, make sure that pcscd
daemon is running and has correct access permissions to USB
devices.
"
readme.gentoo_create_doc
doman "${S}"/man/ykman.1
}
pkg_postinst() {
readme.gentoo_print_elog
}
|
GitWeb
