blob: f0cc6e51b353534f2a9315078d83fd58f4163598 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$
EAPI=5
PYTHON_COMPAT=( python{2_7,3_3,3_4,3_5} pypy pypy3 )
inherit distutils-r1
DESCRIPTION="Rapid multi-Python deployment"
HOMEPAGE="http://codespeak.net/execnet/ https://pypi.python.org/pypi/execnet/"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
IUSE="doc test"
RDEPEND=">=dev-python/apipkg-1.4[${PYTHON_USEDEP}]"
DEPEND="${RDEPEND}
dev-python/setuptools[${PYTHON_USEDEP}]
dev-python/setuptools_scm[${PYTHON_USEDEP}]
doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
test? ( dev-python/pytest[${PYTHON_USEDEP}] )"
#PATCHES=( "${FILESDIR}"/1.2.0-tests.patch )
python_prepare_all() {
# Remove doctest that access an i'net site
rm doc/example/test_info.txt || die
distutils-r1_python_prepare_all
}
python_compile_all() {
use doc && emake -C doc html
}
python_test() {
# https://bitbucket.org/hpk42/execnet/issue/10
unset PYTHONDONTWRITEBYTECODE
py.test testing || die "Tests fail with ${EPYTHON}"
}
python_install_all() {
use doc && local HTML_DOCS=( doc/_build/html/. )
distutils-r1_python_install_all
}
|
GitWeb
