blob: 23e80226cf30f489f5e548ee3879c0481aa22fd4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
|
# Copyright 1999-2016 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$
EAPI=6
PYTHON_COMPAT=( python{2_7,3_4,3_5} )
inherit distutils-r1 virtualx
DESCRIPTION="Python tools to manipulate graphs and complex networks"
HOMEPAGE="http://networkx.github.io/ https://github.com/networkx/networkx"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~arm64 ~ppc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
IUSE="doc examples test"
REQUIRED_USE="doc? ( || ( $(python_gen_useflags 'python2*') ) )"
COMMON_DEPEND="
dev-python/matplotlib[${PYTHON_USEDEP}]
sci-libs/scipy[${PYTHON_USEDEP}]"
DEPEND="
dev-python/setuptools[${PYTHON_USEDEP}]
doc? (
dev-python/sphinx[${PYTHON_USEDEP}]
dev-python/matplotlib[${PYTHON_USEDEP}]
$(python_gen_cond_dep 'dev-python/numpydoc[${PYTHON_USEDEP}]' python2_7)
$(python_gen_cond_dep 'dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]' python2_7 python{3_3,3_4})
)
test? (
${COMMON_DEPEND}
dev-python/nose[${PYTHON_USEDEP}]
$(python_gen_cond_dep 'media-gfx/pydot[${PYTHON_USEDEP}]' python2_7)
)"
RDEPEND="
>=dev-python/decorator-3.4.0[${PYTHON_USEDEP}]
examples? (
${COMMON_DEPEND}
dev-python/pygraphviz[${PYTHON_USEDEP}]
dev-python/pyparsing[${PYTHON_USEDEP}]
dev-python/pyyaml[${PYTHON_USEDEP}]
)"
pkg_setup() {
use doc && DISTUTILS_ALL_SUBPHASE_IMPLS=( 'python2*' )
}
python_prepare_all() {
# Avoid d'loading of file objects.inv from 2 sites of python docs
sed -e "s/'sphinx.ext.intersphinx', //" -i doc/source/conf.py || die
distutils-r1_python_prepare_all
}
python_compile_all() {
# https://github.com/networkx/networkx/issues/1263
if use doc; then
sed \
-e "s:^\t\./:\t${PYTHON} :g" \
-i doc/Makefile || die
emake -C doc html
fi
}
python_test() {
virtx nosetests -vv || die
}
python_install_all() {
# Oh my.
rm -r "${ED}"usr/share/doc/${P} || die
use doc && local HTML_DOCS=( doc/build/html/. )
use examples && dodoc -r examples
distutils-r1_python_install_all
}
|
GitWeb