Add net-analyzer/wireshark-2.4.3

2 files changed, 310 insertions, 0 deletions

diff --git a/net-analyzer/wireshark/Manifest b/net-analyzer/wireshark/Manifest
index ece3b45f..7e50e90c 100644
--- a/net-analyzer/wireshark/Manifest
+++ b/net-analyzer/wireshark/Manifest
@@ -6,7 +6,9 @@ DIST wireshark-2.2.5.tar.bz2 32297102 SHA256 75dd88d3d6336559e5b0b72077d8a772a98
 DIST wireshark-2.2.6.tar.bz2 32317335 SHA256 f627d51eda85f5ae5f5c8c9fc1f6539ffc2a270dd7500dc7f67490a8534ca849 SHA512 d373254801b2d9ae248ff45be09ac36e1916b832430b8f57271421cbd2113c1ffa914ef23c7a1e704d8d5f666f0d4de5bcd9ef9d3801686a35511a5f2a230f3f WHIRLPOOL 859588103ea21fa4e8511a873af81d50e053c5a8b3a92bca2fca317e2ab3e8c4e0e37d89102b887d88a0ef7c6fc90ca45667a43466ac0d71f4ffeec4b9bbf0e0
 DIST wireshark-2.2.7.tar.bz2 32309420 SHA256 689ddf62221b152779d8846ab5b2063cc7fd41ec1a9f04eefab09b5d5486dbb5 SHA512 417836810eb895b3f2a6ac1cfd138fb0275382ea2edc60fc5f5e5f8ce433b56b8120aa8b58b4f77296986630fdf49e4c5c3859b2c2c5e26b1ce0651393b7d716 WHIRLPOOL 0361821da9c113a8de1339cc48cae0291be84bcffb1ba34b1fc3f457b22525329e954a2060f7eef25bca550d0ccdaf4a9e9587d35394b0abd9b0d38bc6023e44
 DIST wireshark-2.4.2.tar.xz 28791712 SHA256 d1acb24735fd35e18e9b7a0555ec58277c2b87da45a19ebeb8087c3dda55f47d SHA512 212964482a1e45af490ef78b3f2465384f84c007a76c3a99e8de0e2c37d933fb34b0da5631f4a36ca12d2fa7cc4376d3d405cbe7f7113791ea09dba7e5915417 WHIRLPOOL 245454643e138c61ccb380ae236482fea702cf4c0507de1c1d3d6dc9f7312809533db7b0fba585f95b8caf5b76affa4da23ad263b8f95174dfbb9c2ee3300177
+DIST wireshark-2.4.3.tar.xz 28807920 SHA256 189495996b68940626cb53b31c8902fa1bb5a96b61217cea42734c13925ff12e SHA512 4344b9efeda3afba4b13bb468f7a12c4565da96c6182a8203cc5815baa11e7d84f3f11003b4289c6c11391cfb590b8c0319268196cc646a8f0226c432e9bb433 WHIRLPOOL 08c6885d5723c9c1a0ffce26a30ef5b9c10b3159929938839b234a91336b7762aa78842e824f8bcf6448ee7a93ae8af2687b73a16b19870b8db4176ccd07d8c2
 EBUILD wireshark-2.2.5.ebuild 7009 SHA256 443f20c2b5fdfe45f8a627ef624c2b9c9cc1c72e9061fbb3ce6f569483f51540 SHA512 11449e44f8027a9f54aa50e50869857161ddd6913481b97edc957e575ac62ecffda1e2f4e0825ba41804736a9c375a7db5f9cf37e7d4de7e697517e65291b652 WHIRLPOOL e6385f7fb223eb9f78fa7490cfa442b2e24153e14f17bc53a5b2fa78a1ac2d11dc9451db33ed92cb7ab3cb90b3c2009ca0a06b9f2ff1056bec4a8e55ae9ee3ea
 EBUILD wireshark-2.2.6.ebuild 7011 SHA256 87b514f46da04664d882f12a09a6ebe4bae0c3efd438241cff73fa045112cd35 SHA512 b5467bcdeccf633d7c4604b9168b02368bf03f416a9adce162afe6b8eaddc0da98bbfcec83d5fd3c0cac630fa80194d57420c67e44e26e538a27bab292cdb21e WHIRLPOOL 022af3d6d010d7e11a0d5c179ebc6bc0129270b9280554a14e110cfcd1fad817a3a2010848da2175a25cfc366d5625e28d1616309c4d3ee76971d62436e4f06e
 EBUILD wireshark-2.2.7.ebuild 6999 SHA256 7acab78bef9fd4e46fad93c0e27d7db4adfecd6ef0ea6e4cb9c2374d5fafe2f6 SHA512 8904e674b8ae7748abe6c412f113467fe52aec35f87f130d09dffdef28655ccdf376b1050a7c45bd01dd9166ab63cc9f41f413769097a9a9cf81fa99afe027f8 WHIRLPOOL c38c207d9146f4d1307c6fe3d35840140b9bb1a18556e5e78aea0b970784f587e2cfe54a6294f2dd9393ff01ba1a26006a19368a693c027070b48a0b5d91407d
 EBUILD wireshark-2.4.2.ebuild 7909 SHA256 a2163bf6cc8085135a33113f2b852f98480c99b3775da9adb018d1280560cf8c SHA512 f2f2b26e1c7660383dd60401d5d4dab8579b7f02384fd85396725bff0e127af8d40953323f6ef488440aabbdea496af483d9c82a55c7921840e7023943469eea WHIRLPOOL 0678c3a7219196ae58bc3d997a7cffcd4ddcdc5cadb8604588b0e92b302daf814532ef670cd4a9358142f35dcfb94d58fd21192e8c0eb89d0c28973a10946911
+EBUILD wireshark-2.4.3.ebuild 7996 SHA256 9f8f1567d0c26460fc8f8b4424d337af32968ec70bbbec6fbb8c788f157fd727 SHA512 75567db075eea9e8b76d9f0527503a0f443ef75b2a7592a1394d18430389a17f615594856b928655ab1f7a1b2e1ff92061e74619ce2e4379db8e7d40c02975ee WHIRLPOOL e393008a7f9adb8cf671c724cd6c6d128a92f4334c1572138522f39f2aa5ec7af0722e4ff8def6af983ae39b596b7a1d93191df47500cabc033e9aca32767f1f
diff --git a/net-analyzer/wireshark/wireshark-2.4.3.ebuild b/net-analyzer/wireshark/wireshark-2.4.3.ebuild
new file mode 100644
index 00000000..0388897b
--- /dev/null
+++ b/net-analyzer/wireshark/wireshark-2.4.3.ebuild
@@ -0,0 +1,308 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit autotools eutils fcaps flag-o-matic gnome2-utils multilib qmake-utils user xdg-utils
+
+DESCRIPTION="A network protocol analyzer formerly known as ethereal"
+HOMEPAGE="https://www.wireshark.org/"
+SRC_URI="${HOMEPAGE}download/src/all-versions/${P/_/}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0/${PV}"
+KEYWORDS="amd64 ~arm ~arm64 ~hppa ia64 ppc ppc64 x86 ~x86-fbsd"
+IUSE="
+	adns androiddump +capinfos +caps +captype ciscodump cpu_flags_x86_sse4_2 crypt
+	+dftest doc doc-pdf +dumpcap +editcap geoip gtk kerberos libssh libxml2 lua
+	lz4 +mergecap +netlink nghttp2 +pcap portaudio +qt5 +randpkt +randpktdump
+	+reordercap sbc selinux +sharkd smi snappy spandsp sshdump ssl +text2pcap
+	tfshark +tshark +udpdump zlib
+"
+REQUIRED_USE="
+	ciscodump? ( libssh )
+	sshdump? ( libssh )
+	ssl? ( crypt )
+"
+
+S=${WORKDIR}/${P/_/}
+
+CDEPEND="
+	>=dev-libs/glib-2.14:2
+	crypt? ( dev-libs/libgcrypt:0 )
+	netlink? ( dev-libs/libnl:3 )
+	adns? ( >=net-dns/c-ares-1.5 )
+	caps? ( sys-libs/libcap )
+	geoip? ( dev-libs/geoip )
+	gtk? (
+		x11-libs/gdk-pixbuf
+		x11-libs/gtk+:3
+		x11-libs/pango
+		x11-misc/xdg-utils
+	)
+	kerberos? ( virtual/krb5 )
+	libssh? ( >=net-libs/libssh-0.6 )
+	libxml2? ( dev-libs/libxml2 )
+	lua? ( >=dev-lang/lua-5.1:* )
+	lz4? ( app-arch/lz4 )
+	nghttp2? ( net-libs/nghttp2 )
+	pcap? ( net-libs/libpcap )
+	portaudio? ( media-libs/portaudio )
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtmultimedia:5
+		dev-qt/qtprintsupport:5
+		dev-qt/qtwidgets:5
+		|| (
+			media-libs/speexdsp
+			<media-libs/speex-1.2.0
+		)
+		x11-misc/xdg-utils
+	)
+	sbc? ( media-libs/sbc )
+	smi? ( net-libs/libsmi )
+	snappy? ( app-arch/snappy )
+	spandsp? ( media-libs/spandsp )
+	ssl? ( net-libs/gnutls:= )
+	zlib? ( sys-libs/zlib !=sys-libs/zlib-1.2.4 )
+"
+# We need perl for `pod2html`.  The rest of the perl stuff is to block older
+# and broken installs. #455122
+DEPEND="
+	${CDEPEND}
+	dev-lang/perl
+	!<virtual/perl-Pod-Simple-3.170
+	!<perl-core/Pod-Simple-3.170
+	doc? (
+		app-doc/doxygen
+		app-text/asciidoc
+		dev-libs/libxml2
+		dev-libs/libxslt
+		doc-pdf? ( dev-java/fop )
+		www-client/lynx
+	)
+	qt5? (
+		dev-qt/linguist-tools:5
+	)
+	sys-devel/bison
+	sys-devel/flex
+	virtual/pkgconfig
+"
+RDEPEND="
+	${CDEPEND}
+	gtk? ( virtual/freedesktop-icon-theme )
+	qt5? ( virtual/freedesktop-icon-theme )
+	selinux? ( sec-policy/selinux-wireshark )
+"
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.99.8-qtchooser.patch
+	"${FILESDIR}"/${PN}-2.1.0-sse4_2-r1.patch
+	"${FILESDIR}"/${PN}-2.4-androiddump.patch
+	"${FILESDIR}"/${PN}-99999999-androiddump.patch
+)
+
+pkg_setup() {
+	enewgroup wireshark
+}
+
+src_prepare() {
+	default
+
+	eautoreconf
+}
+
+src_configure() {
+	local myconf
+
+	# Workaround bug #213705. If krb5-config --libs has -lcrypto then pass
+	# --with-ssl to ./configure. (Mimics code from acinclude.m4).
+	if use kerberos; then
+		case $(krb5-config --libs) in
+			*-lcrypto*)
+				ewarn "Kerberos was built with ssl support: linkage with openssl is enabled."
+				ewarn "Note there are annoying license incompatibilities between the OpenSSL"
+				ewarn "license and the GPL, so do your check before distributing such package."
+				myconf+=( "--with-ssl" )
+				;;
+		esac
+	fi
+
+	# Enable wireshark binary with any supported GUI toolkit (bug #473188)
+	if use gtk || use qt5; then
+		myconf+=( "--enable-wireshark" )
+	else
+		myconf+=( "--disable-wireshark" )
+	fi
+
+	if ! use qt5; then
+		myconf+=( "--with-qt=no" )
+	fi
+
+	if use qt5; then
+		export QT_MIN_VERSION=5.3.0
+		append-cxxflags -fPIC -DPIC
+	fi
+
+	# Using '-isysroot' to use the macOS SDK fails due to stub libraries and
+	# missing headers...
+	sed -e '/SDKFLAGS="-isysroot $SDKPATH"/d' \
+		-i macosx-setup.sh \
+	|| die "Could not remove sysroot/SDK injection from macOS setup script: ${?}"
+	sed -e 's/ -isysroot $SDKPATH / /g' \
+		-i m4/ws_osx.m4 configure \
+	|| die "Could not remove sysroot/SDK injection from m4 macros & configure: ${?}"
+
+	# Hack around inability to disable doxygen/fop doc generation
+	use doc || export ac_cv_prog_HAVE_DOXYGEN=false
+	use doc-pdf || export ac_cv_prog_HAVE_FOP=false
+
+	# dumpcap requires libcap
+	# --disable-profile-build bugs #215806, #292991, #479602
+	econf \
+		$(use androiddump && use pcap && echo --enable-androiddump-use-libpcap=yes) \
+		$(use dumpcap && use_with pcap dumpcap-group wireshark) \
+		$(use_enable androiddump) \
+		$(use_enable capinfos) \
+		$(use_enable captype) \
+		$(use_enable ciscodump) \
+		$(use_enable dftest) \
+		$(use_enable dumpcap) \
+		$(use_enable editcap) \
+		$(use_enable mergecap) \
+		$(use_enable randpkt) \
+		$(use_enable randpktdump) \
+		$(use_enable reordercap) \
+		$(use_enable sharkd) \
+		$(use_enable sshdump) \
+		$(use_enable text2pcap) \
+		$(use_enable tfshark) \
+		$(use_enable tshark) \
+		$(use_enable udpdump) \
+		$(use_with adns c-ares) \
+		$(use_with caps libcap) \
+		$(use_with crypt gcrypt) \
+		$(use_with geoip) \
+		$(use_with gtk gtk 3) \
+		$(use_with kerberos krb5) \
+		$(use_with libssh) \
+		$(use_with libxml2) \
+		$(use_with lua) \
+		$(use_with lz4) \
+		$(use_with nghttp2) \
+		$(use_with pcap) \
+		$(use_with portaudio) \
+		$(use_with sbc) \
+		$(use_with smi libsmi) \
+		$(use_with snappy) \
+		$(use_with spandsp) \
+		$(use_with ssl gnutls) \
+		$(use_with zlib) \
+		$(usex cpu_flags_x86_sse4_2 --enable-sse4_2 '') \
+		$(usex netlink --with-libnl=3 --without-libnl) \
+		$(usex qt5 --with-qt=5 '') \
+		$(usex qt5 LRELEASE=$(qt5_get_bindir)/lrelease '') \
+		$(usex qt5 MOC=$(qt5_get_bindir)/moc '') \
+		$(usex qt5 RCC=$(qt5_get_bindir)/rcc '') \
+		$(usex qt5 UIC=$(qt5_get_bindir)/uic '') \
+		--disable-profile-build \
+		--disable-warnings-as-errors \
+		--sysconfdir="${EPREFIX}"/etc/wireshark \
+		${myconf[@]}
+
+	# Remove any remaining macOS SDK usage...
+	find . -name Makefile -exec sed -e 's/ -isysroot [^ ]\+ / /g' -i {} +
+}
+
+src_compile() {
+	default
+
+	if use doc; then
+		emake -j1 -C docbook
+		if use doc-pdf; then
+			addpredict "/root/.java"
+			emake -C docbook all-pdf
+		fi
+	fi
+}
+
+src_install() {
+	default
+
+	# FAQ is not required as is installed from help/faq.txt
+	dodoc AUTHORS ChangeLog NEWS README{,.bsd,.linux,.macos,.vmware} \
+		doc/{randpkt.txt,README*}
+
+	if use doc; then
+		docinto /usr/share/doc/${PF}/html
+		dodoc -r docbook/{release-notes.html,ws{d,u}g_html{,_chunked}}
+		if use doc-pdf; then
+			docinto /usr/share/doc/${PF}/pdf/
+			dodoc docbook/{developer,user}-guide-{a4,us}.pdf docbook/release-notes.pdf
+		fi
+	fi
+
+	# install headers
+	local wsheader
+	for wsheader in \
+		config.h \
+		epan/*.h \
+		epan/crypt/*.h \
+		epan/dfilter/*.h \
+		epan/dissectors/*.h \
+		epan/ftypes/*.h \
+		epan/wmem/*.h \
+		register.h \
+		wiretap/*.h \
+		ws_diag_control.h \
+		ws_symbol_export.h \
+		wsutil/*.h
+	do
+		insinto /usr/include/wireshark/$( dirname ${wsheader} )
+		doins ${wsheader}
+	done
+
+	#with the above this really shouldn't be needed, but things may be looking in wiretap/ instead of wireshark/wiretap/
+	insinto /usr/include/wiretap
+	doins wiretap/wtap.h
+
+	if use gtk || use qt5; then
+		local c d
+		for c in hi lo; do
+			for d in 16 32 48; do
+				insinto /usr/share/icons/${c}color/${d}x${d}/apps
+				newins image/${c}${d}-app-wireshark.png wireshark.png
+			done
+		done
+		for d in 16 24 32 48 64 128 256 ; do
+			insinto /usr/share/icons/hicolor/${d}x${d}/mimetypes
+			newins image/WiresharkDoc-${d}.png application-vnd.tcpdump.pcap.png
+		done
+	fi
+
+	prune_libtool_files
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+
+	# Add group for users allowed to sniff.
+	enewgroup wireshark
+
+	if use pcap; then
+		fcaps -o 0 -g wireshark -m 4710 -M 0710 \
+			cap_dac_read_search,cap_net_raw,cap_net_admin \
+			"${EROOT}"/usr/bin/dumpcap
+	fi
+
+	ewarn "NOTE: To capture traffic with wireshark as normal user you have to"
+	ewarn "add yourself to the wireshark group. This security measure ensures"
+	ewarn "that only trusted users are allowed to sniff your traffic."
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+}